Load QML modules in a central place + dummy QML slideshow.

src/qml/CMakeLists.txt

@@ -0,0 +1 @@
+add_subdirectory( calamares )

src/qml/calamares/CMakeLists.txt

@@ -0,0 +1,27 @@
+file( GLOB SUBDIRECTORIES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "*" )
+
+# Iterate over all the subdirectories which have a qmldir file, copy them over to the build dir,
+# and install them into share/calamares/qml/calamares
+foreach( SUBDIRECTORY ${SUBDIRECTORIES} )
+    if( IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/${SUBDIRECTORY}"
+        AND EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${SUBDIRECTORY}/qmldir" )
+
+        set( QML_DIR share/calamares/qml )
+        set( QML_MODULE_DESTINATION ${QML_DIR}/calamares/${SUBDIRECTORY} )
+
+        # We glob all the files inside the subdirectory, and we make sure they are
+        # synced with the bindir structure and installed.
+        file( GLOB QML_MODULE_FILES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}/${SUBDIRECTORY} "${SUBDIRECTORY}/*" )
+        foreach( QML_MODULE_FILE ${QML_MODULE_FILES} )
+            if( NOT IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/${SUBDIRECTORY}/${QML_MODULE_FILE} )
+                configure_file( ${SUBDIRECTORY}/${QML_MODULE_FILE} ${SUBDIRECTORY}/${QML_MODULE_FILE} COPYONLY )
+
+                install( FILES ${CMAKE_CURRENT_BINARY_DIR}/${SUBDIRECTORY}/${QML_MODULE_FILE}
+                         DESTINATION ${QML_MODULE_DESTINATION} )
+            endif()
+        endforeach()
+
+        message( "-- ${BoldYellow}Configured QML module: ${BoldRed}calamares.${SUBDIRECTORY}${ColorReset}" )
+
+    endif()
+endforeach()

src/qml/calamares/slideshow/Presentation.qml

@@ -0,0 +1,201 @@
+/****************************************************************************
+**
+** Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the QML Presentation System.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and Digia.  For licensing terms and
+** conditions see http://qt.digia.com/licensing.  For further information
+** use the contact form at http://qt.digia.com/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 2.1 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU Lesser General Public License version 2.1 requirements
+** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
+**
+** In addition, as a special exception, Digia gives you certain additional
+** rights.  These rights are described in the Digia Qt LGPL Exception
+** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 3.0 as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU General Public License version 3.0 requirements will be
+** met: http://www.gnu.org/copyleft/gpl.html.
+**
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+
+import QtQuick 2.0
+import QtQuick.Window 2.0
+
+Item {
+    id: root
+
+    property variant slides: []
+    property int currentSlide;
+
+    property bool showNotes: false;
+    property bool allowDelay: true;
+
+    property color titleColor: textColor;
+    property color textColor: "black"
+    property string fontFamily: "Helvetica"
+    property string codeFontFamily: "Courier New"
+
+    // Private API
+    property bool _faded: false
+    property int _userNum;
+
+    Component.onCompleted: {
+        var slideCount = 0;
+        var slides = [];
+        for (var i=0; i<root.children.length; ++i) {
+            var r = root.children[i];
+            if (r.isSlide) {
+                slides.push(r);
+            }
+        }
+
+        root.slides = slides;
+        root._userNum = 0;
+
+        // Make first slide visible...
+        if (root.slides.length > 0) {
+            root.currentSlide = 0;
+            root.slides[root.currentSlide].visible = true;
+        }
+    }
+
+    function switchSlides(from, to, forward) {
+        from.visible = false
+        to.visible = true
+        return true
+    }
+
+    function goToNextSlide() {
+        root._userNum = 0
+        if (_faded)
+            return
+        if (root.slides[currentSlide].delayPoints) {
+            if (root.slides[currentSlide]._advance())
+                return;
+        }
+        if (root.currentSlide + 1 < root.slides.length) {
+            var from = slides[currentSlide]
+            var to = slides[currentSlide + 1]
+            if (switchSlides(from, to, true)) {
+                currentSlide = currentSlide + 1;
+                root.focus = true;
+            }
+        }
+    }
+
+    function goToPreviousSlide() {
+        root._userNum = 0
+        if (root._faded)
+            return
+        if (root.currentSlide - 1 >= 0) {
+            var from = slides[currentSlide]
+            var to = slides[currentSlide - 1]
+           if (switchSlides(from, to, false)) {
+                currentSlide = currentSlide - 1;
+               root.focus = true;
+           }
+        }
+    }
+
+    function goToUserSlide() {
+        --_userNum;
+        if (root._faded || _userNum >= root.slides.length)
+            return
+        if (_userNum < 0)
+            goToNextSlide()
+        else if (root.currentSlide != _userNum) {
+            var from = slides[currentSlide]
+            var to = slides[_userNum]
+           if (switchSlides(from, to, _userNum > currentSlide)) {
+                currentSlide = _userNum;
+               root.focus = true;
+           }
+        }
+    }
+
+    focus: true
+
+    Keys.onSpacePressed: goToNextSlide()
+    Keys.onRightPressed: goToNextSlide()
+    Keys.onDownPressed: goToNextSlide()
+    Keys.onLeftPressed: goToPreviousSlide()
+    Keys.onUpPressed: goToPreviousSlide()
+    Keys.onEscapePressed: Qt.quit()
+    Keys.onPressed: {
+        if (event.key >= Qt.Key_0 && event.key <= Qt.Key_9)
+            _userNum = 10 * _userNum + (event.key - Qt.Key_0)
+        else {
+            if (event.key == Qt.Key_Return || event.key == Qt.Key_Enter)
+                goToUserSlide();
+            else if (event.key == Qt.Key_Backspace)
+                goToPreviousSlide();
+            else if (event.key == Qt.Key_C)
+                root._faded = !root._faded;
+            _userNum = 0;
+        }
+    }
+
+    Rectangle {
+        z: 1000
+        color: "black"
+        anchors.fill: parent
+        opacity: root._faded ? 1 : 0
+        Behavior on opacity { NumberAnimation { duration: 250 } }
+    }
+
+    MouseArea {
+        id: mouseArea
+        anchors.fill: parent
+        acceptedButtons: Qt.LeftButton | Qt.RightButton
+        onClicked: {
+            if (mouse.button == Qt.RightButton)
+                goToPreviousSlide()
+            else
+                goToNextSlide()
+        }
+        onPressAndHold: goToPreviousSlide(); //A back mechanism for touch only devices
+    }
+
+    Window {
+        id: notesWindow;
+        width: 400
+        height: 300
+
+        title: "QML Presentation: Notes"
+        visible: root.showNotes
+
+        Text {
+            anchors.fill: parent
+            anchors.margins: parent.height * 0.1;
+
+            font.pixelSize: 16
+            wrapMode: Text.WordWrap
+
+            property string notes: root.slides[root.currentSlide].notes;
+            text: notes == "" ? "Slide has no notes..." : notes;
+            font.italic: notes == "";
+        }
+    }
+}

src/qml/calamares/slideshow/Slide.qml

@@ -0,0 +1,201 @@
+/****************************************************************************
+**
+** Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the QML Presentation System.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and Digia.  For licensing terms and
+** conditions see http://qt.digia.com/licensing.  For further information
+** use the contact form at http://qt.digia.com/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 2.1 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU Lesser General Public License version 2.1 requirements
+** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
+**
+** In addition, as a special exception, Digia gives you certain additional
+** rights.  These rights are described in the Digia Qt LGPL Exception
+** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 3.0 as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU General Public License version 3.0 requirements will be
+** met: http://www.gnu.org/copyleft/gpl.html.
+**
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+
+import QtQuick 2.0
+
+Item {
+    /*
+      Slides can only be instantiated as a direct child of a Presentation {} as they rely on
+      several properties there.
+     */
+
+    id: slide
+
+    property bool isSlide: true;
+
+    property bool delayPoints: false;
+    property int _pointCounter: 0;
+    function _advance() {
+        if (!parent.allowDelay)
+            return false;
+
+        _pointCounter = _pointCounter + 1;
+        if (_pointCounter < content.length)
+            return true;
+        _pointCounter = 0;
+        return false;
+    }
+
+    property string title;
+    property variant content: []
+    property string centeredText
+    property string writeInText;
+    property string notes;
+
+    property real fontSize: parent.height * 0.05
+    property real fontScale: 1
+
+    property real baseFontSize: fontSize * fontScale
+    property real titleFontSize: fontSize * 1.2 * fontScale
+    property real bulletSpacing: 1
+
+    property real contentWidth: width
+
+    // Define the slide to be the "content area"
+    x: parent.width * 0.05
+    y: parent.height * 0.2
+    width: parent.width * 0.9
+    height: parent.height * 0.7
+
+    property real masterWidth: parent.width
+    property real masterHeight: parent.height
+
+    property color titleColor: parent.titleColor;
+    property color textColor: parent.textColor;
+    property string fontFamily: parent.fontFamily;
+    property int textFormat: Text.PlainText
+
+    visible: false
+
+    Text {
+        id: titleText
+        font.pixelSize: titleFontSize
+        text: title;
+        anchors.horizontalCenter: parent.horizontalCenter
+        anchors.bottom: parent.top
+        anchors.bottomMargin: parent.fontSize * 1.5
+        font.bold: true;
+        font.family: slide.fontFamily
+        color: slide.titleColor
+        horizontalAlignment: Text.Center
+        z: 1
+    }
+
+    Text {
+        id: centeredId
+        width: parent.width
+        anchors.centerIn: parent
+        anchors.verticalCenterOffset: - parent.y / 3
+        text: centeredText
+        horizontalAlignment: Text.Center
+        font.pixelSize: baseFontSize
+        font.family: slide.fontFamily
+        color: slide.textColor
+        wrapMode: Text.Wrap
+    }
+
+    Text {
+        id: writeInTextId
+        property int length;
+        font.family: slide.fontFamily
+        font.pixelSize: baseFontSize
+        color: slide.textColor
+
+        anchors.fill: parent;
+        wrapMode: Text.Wrap
+
+        text: slide.writeInText.substring(0, length);
+
+        NumberAnimation on length {
+            from: 0;
+            to: slide.writeInText.length;
+            duration: slide.writeInText.length * 30;
+            running: slide.visible && parent.visible && slide.writeInText.length > 0
+        }
+
+        visible: slide.writeInText != undefined;
+    }
+
+
+    Column {
+        id: contentId
+        anchors.fill: parent
+
+        Repeater {
+            model: content.length
+
+            Row {
+                id: row
+
+                function decideIndentLevel(s) { return s.charAt(0) == " " ? 1 + decideIndentLevel(s.substring(1)) : 0 }
+                property int indentLevel: decideIndentLevel(content[index])
+                property int nextIndentLevel: index < content.length - 1 ? decideIndentLevel(content[index+1]) : 0
+                property real indentFactor: (10 - row.indentLevel * 2) / 10;
+
+                height: text.height + (nextIndentLevel == 0 ? 1 : 0.3) * slide.baseFontSize * slide.bulletSpacing
+                x: slide.baseFontSize * indentLevel
+                visible: (!slide.parent.allowDelay || !delayPoints) || index <= _pointCounter
+
+                Rectangle {
+                    id: dot
+                    y: baseFontSize * row.indentFactor / 2
+                    width: baseFontSize / 4
+                    height: baseFontSize / 4
+                    color: slide.textColor
+                    radius: width / 2
+                    smooth: true
+                    opacity: text.text.length == 0 ? 0 : 1
+                }
+
+                Rectangle {
+                    id: space
+                    width: dot.width * 2
+                    height: 1
+                    color: "#00ffffff"
+                }
+
+                Text {
+                    id: text
+                    width: slide.contentWidth - parent.x - dot.width - space.width
+                    font.pixelSize: baseFontSize * row.indentFactor
+                    text: content[index]
+                    textFormat: slide.textFormat
+                    wrapMode: Text.WordWrap
+                    color: slide.textColor
+                    horizontalAlignment: Text.AlignLeft
+                    font.family: slide.fontFamily
+                }
+            }
+        }
+    }
+
+}

src/qml/calamares/slideshow/qmldir

@@ -0,0 +1,4 @@
+module calamares.slideshow
+Presentation 1.0 Presentation.qml
+Slide 1.0 Slide.qml
+