aaaf56e71c
2001-07-05 Bradford Hovinen <hovinen@ximian.com> * capplets/Makefile.am: Removed rules pertaining to sound-properties * capplets/sound-properties-capplet.c (set_moniker_cb): Change BonoboPropertyEditor to BonoboPEditor * configure.in: Update AC_INIT to use correct directory name (AC_OUTPUT): Update to current directory structure * Makefile.am (SUBDIRS): Update to current directory structure * capplets/Makefile.am (always_built_SUBDIRS): Updated to current directory structure * bonobo-moniker-archiver.c (archiver_resolve): Update call to Bonobo_ConfigDatabase_addDatabase * bonobo-config-archiver.h: Fix include directories * Makefile.am (INCLUDES): Update to use pkg-config standards; add BONOBO_CFLAGS Include configuration moniker-related material (SUBDIRS): Remove (bin_PROGRAMS): Added ximian-archiver * capplets/keyboard/prefs-widget.c (set_scale): Add appropriate casts * capplets/rollback/Makefile.am (INCLUDES): (rollback_capplet_LDADD): Update to include ximian_archiver stuff correctly
147 lines
4.1 KiB
Text
147 lines
4.1 KiB
Text
AC_INIT(control-center)
|
|
|
|
AM_CONFIG_HEADER(config.h)
|
|
AM_INIT_AUTOMAKE(control-center, 1.3.1)
|
|
|
|
AM_MAINTAINER_MODE
|
|
|
|
dnl
|
|
dnl let applications configure for gnome
|
|
dnl
|
|
gnome_cv_use_gnome=yes
|
|
|
|
|
|
AM_ACLOCAL_INCLUDE(macros)
|
|
GNOME_INIT
|
|
GNOME_COMPILE_WARNINGS
|
|
|
|
AC_ISC_POSIX
|
|
AC_PROG_CC
|
|
AC_STDC_HEADERS
|
|
AC_ARG_PROGRAM
|
|
AM_PROG_LIBTOOL
|
|
AM_PROG_LEX
|
|
AC_PROG_YACC
|
|
|
|
dnl utility conditional
|
|
AM_CONDITIONAL(FALSE, test "x" = "y")
|
|
|
|
ALL_LINGUAS="az ca cs da de el en_GB es et fi fr ga gl hr hu it ja ko lt nl no pl pt pt_BR ro ru sk sl sv tr uk zh_CN.GB2312 zh_TW.Big5"
|
|
AM_GNOME_GETTEXT
|
|
|
|
GNOME_XML_CHECK
|
|
XML_CFLAGS=`gnome-config --cflags xml`
|
|
AC_SUBST(XML_CFLAGS)
|
|
|
|
AM_PATH_LIBGLADE(,,"gnome")
|
|
|
|
AC_CHECK_HEADERS(dlfcn.h dl.h)
|
|
AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl",[
|
|
AC_CHECK_LIB(dld, shl_load, DL_LIB="-ldld",[
|
|
AC_CHECK_FUNCS(dlopen, DL_LIB="",
|
|
AC_MSG_ERROR(Dynamic linking is not available on this platform. Some
|
|
apps, like panel, will not run properly.))
|
|
])])
|
|
AC_SUBST(DL_LIB)
|
|
|
|
AC_CHECK_FUNCS(usleep)
|
|
AC_CHECK_FUNCS(putenv,[AC_DEFINE(HAVE_PUTENV)])
|
|
AC_CHECK_FUNCS(setenv,[AC_DEFINE(HAVE_SETENV)])
|
|
|
|
dnl keyboard-properties-capplet
|
|
AC_CHECK_HEADERS(X11/extensions/xf86misc.h, XF86MISC_LIBS="-lXxf86misc")
|
|
AC_SUBST(XF86MISC_LIBS)
|
|
|
|
AM_PATH_LIBGLADE(,AC_MSG_ERROR([You must have LibGlade installed.]), gnome)
|
|
|
|
dnl esd-manager
|
|
have_libesd=no
|
|
AM_PATH_ESD(,have_libesd=yes,
|
|
[AC_MSG_WARN([*** \`esd-manager' will not be built ***])])
|
|
AM_CONDITIONAL(HAVE_LIBESD, test yes = $have_libesd)
|
|
if test "$have_libesd" = yes; then
|
|
AC_DEFINE(HAVE_ESD)
|
|
AC_DEFINE(HAVE_LIBESD)
|
|
fi
|
|
|
|
dnl session-properties
|
|
AM_CONDITIONAL(SESSION, test "$GNOME_HAVE_SM" = true)
|
|
|
|
AM_PATH_IMLIB(1.8.2, , [
|
|
echo "ERROR: Needs a system with Imlib 1.8.2 or higher"
|
|
echo "You can obtain it from:"
|
|
echo "ftp://ftp.enlightenment.org/pub/enlightenment/"
|
|
echo "ftp://www.rasterman.com/pub/enlightenment/"
|
|
echo "ftp://ftp.labs.redhat.com/pub/imlib/"
|
|
AC_MSG_ERROR([Fatal Error: no Imlib detected.])])
|
|
|
|
CFLAGS="-O2 -g -Wall $CFLAGS"
|
|
|
|
dnl
|
|
dnl Check for libximian_archiver and set the flag
|
|
dnl HAVE_LIBXIMIAN_ARCHIVER iff it is prsent
|
|
dnl
|
|
AC_MSG_CHECKING(for Ximian archiver library)
|
|
vers=`$GNOME_CONFIG --modversion ximian_archiver 2>/dev/null`
|
|
case "x$vers" in
|
|
xximian-archiver-*)
|
|
AC_DEFINE(HAVE_XIMIAN_ARCHIVER)
|
|
ARCHIVER_MODULE=ximian_archiver
|
|
AC_MSG_RESULT(found)
|
|
;;
|
|
*)
|
|
AC_MSG_RESULT(not found)
|
|
;;
|
|
esac
|
|
|
|
AC_PATH_PROG(PKGCONFIG, pkg-config, no)
|
|
if test "$PKGCONFIG" = no ; then
|
|
AC_MSG_ERROR(pkg-config was not found. Please install version 0.6.0 or newer from http://www.freedesktop.org/software.)
|
|
fi
|
|
|
|
AC_MSG_CHECKING(for pkg-config >= 0.6.0)
|
|
vers=`$PKGCONFIG --version | awk 'BEGIN { FS = "."; } { print $1 * 1000000 + $2 * 1000 + $3}'`
|
|
if test "$vers" -ge 6000; then
|
|
AC_MSG_RESULT(found)
|
|
else
|
|
AC_MSG_ERROR(You need at least pkg-config 0.6.0 or greater for this version of control-center. Please install a newer version from http://www.freedesktop.org/software.)
|
|
fi
|
|
|
|
capplet_modules="libcapplet2 libglade gdk_pixbuf bonobo_conf $ARCHIVER_MODULE"
|
|
|
|
PKG_CHECK_MODULES(CAPPLET, $capplet_modules)
|
|
PKG_CHECK_MODULES(BG_CAPPLET, $capplet_modules gdk_pixbuf_xlib)
|
|
PKG_CHECK_MODULES(SCREENSAVER_CAPPLET, $capplet_modules gal)
|
|
PKG_CHECK_MODULES(ROLLBACK_CAPPLET, $capplet_modules)
|
|
PKG_CHECK_MODULES(VFS_CAPPLET, $capplet_modules)
|
|
PKG_CHECK_MODULES(GNOMECC, gnomeui libglade xml gdk_pixbuf capplet gnomecanvaspixbuf gtkhtml)
|
|
PKG_CHECK_MODULES(RMHELPER, gnomeui gnomecanvaspixbuf)
|
|
PKG_CHECK_MODULES(ARCHIVER, bonobo xml)
|
|
PKG_CHECK_MODULES(MONIKER, bonobo bonobo_conf xml)
|
|
|
|
dnl gnome-vfs doesn't support gnome-config or pkg-config
|
|
VFS_CFLAGS=`gnome-vfs-config --cflags`
|
|
VFS_LIBS=`gnome-vfs-config --libs`
|
|
|
|
VFS_CAPPLET_CFLAGS="$VFS_CAPPLET_CFLAGS $VFS_CFLAGS"
|
|
VFS_CAPPLET_LIBS="$VFS_CAPPLET_LIBS $VFS_LIBS"
|
|
|
|
AC_SUBST(CFLAGS)
|
|
AC_SUBST(LDFLAGS)
|
|
|
|
AC_OUTPUT([
|
|
control-center.spec
|
|
Makefile
|
|
po/Makefile.in
|
|
archiver/Makefile
|
|
control-center/Makefile
|
|
root-manager/Makefile
|
|
capplets/Makefile
|
|
capplets/background/Makefile
|
|
capplets/keyboard/Makefile
|
|
capplets/mouse/Makefile
|
|
capplets/rollback/Makefile
|
|
capplets/screensaver/Makefile
|
|
capplets/screensaver/screensavers/Makefile
|
|
capplets/sound/Makefile
|
|
intl/Makefile])
|