83c8c57761
Now that gnome-session's acceleration helper can print the renderer under Wayland, launch it locally. We need to launch it locally as Wayland is not available at the time gnome-session would launch the helper, as there's no Wayland compositor yet. Note that this code expects the gnome-session helper scripts to live in $libexecdir, but distributions can use --with-gnome-session-libexecdir=DIR to pass another one. https://bugzilla.gnome.org/show_bug.cgi?id=756914
43 lines
1.1 KiB
Text
43 lines
1.1 KiB
Text
dnl as-ac-expand.m4 0.2.0
|
|
dnl autostars m4 macro for expanding directories using configure's prefix
|
|
dnl thomas@apestaart.org
|
|
|
|
dnl AS_AC_EXPAND(VAR, CONFIGURE_VAR)
|
|
dnl example
|
|
dnl AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
|
|
dnl will set SYSCONFDIR to /usr/local/etc if prefix=/usr/local
|
|
|
|
AC_DEFUN([AS_AC_EXPAND],
|
|
[
|
|
EXP_VAR=[$1]
|
|
FROM_VAR=[$2]
|
|
|
|
dnl first expand prefix and exec_prefix if necessary
|
|
prefix_save=$prefix
|
|
exec_prefix_save=$exec_prefix
|
|
|
|
dnl if no prefix given, then use /usr/local, the default prefix
|
|
if test "x$prefix" = "xNONE"; then
|
|
prefix="$ac_default_prefix"
|
|
fi
|
|
dnl if no exec_prefix given, then use prefix
|
|
if test "x$exec_prefix" = "xNONE"; then
|
|
exec_prefix=$prefix
|
|
fi
|
|
|
|
full_var="$FROM_VAR"
|
|
dnl loop until it doesn't change anymore
|
|
while true; do
|
|
new_full_var="`eval echo $full_var`"
|
|
if test "x$new_full_var" = "x$full_var"; then break; fi
|
|
full_var=$new_full_var
|
|
done
|
|
|
|
dnl clean up
|
|
full_var=$new_full_var
|
|
AC_SUBST([$1], "$full_var")
|
|
|
|
dnl restore prefix and exec_prefix
|
|
prefix=$prefix_save
|
|
exec_prefix=$exec_prefix_save
|
|
])
|