89443fe550
The `X-GNOME-Bugzilla-*` entries were for use by bug-buddy, a GNOME 2 technology that's been gone for over a decade. These entries are obsolete and can be removed from all desktop files. The `X-GNOME-Settings-Panel` entry is also obsolete as far as I can tell and only these panels had it in their desktop file: notifications, sharing, sound and user-accounts. These entries can also be removed. After removing the `X-GNOME-Bugzilla-*` entries, the desktop files have no more variables in them. The meson `configure_file` step is therefor pointless—there are no variables to configure. As such the `*.desktop.in.in` files are renamed to `*.desktop.in` to reflect this and `meson.build` files are modified to remove `configure_file` step.
100 lines
2.1 KiB
Meson
100 lines
2.1 KiB
Meson
deps = common_deps + wacom_deps + [
|
|
gnome_rr_dep,
|
|
gnome_settings_dep,
|
|
x11_dep,
|
|
xi_dep
|
|
]
|
|
|
|
cflags += ['-DGNOMELOCALEDIR="@0@"'.format(control_center_localedir)]
|
|
|
|
test_cflags = cflags + ['-DFAKE_AREA']
|
|
|
|
wacom_gresource = gnome.compile_resources(
|
|
'cc-' + cappletname + '-resources',
|
|
cappletname + '.gresource.xml',
|
|
source_dir : '.',
|
|
c_name : 'cc_' + cappletname,
|
|
dependencies : resource_data,
|
|
export : true
|
|
)
|
|
|
|
subdir('calibrator')
|
|
|
|
panels_list += cappletname
|
|
desktop = 'gnome-@0@-panel.desktop'.format(cappletname)
|
|
|
|
i18n.merge_file(
|
|
type : 'desktop',
|
|
input : desktop + '.in',
|
|
output : desktop,
|
|
po_dir : po_dir,
|
|
install : true,
|
|
install_dir : control_center_desktopdir
|
|
)
|
|
|
|
common_sources = files(
|
|
'cc-tablet-tool-map.c',
|
|
'cc-wacom-button-row.c',
|
|
'cc-wacom-device.c',
|
|
'cc-wacom-page.c',
|
|
'cc-wacom-stylus-page.c',
|
|
'cc-wacom-tool.c',
|
|
'gsd-wacom-key-shortcut-button.c'
|
|
)
|
|
|
|
resource_data = files(
|
|
'calibrator/calibrator.ui',
|
|
'calibrator/calibrator.css',
|
|
'calibrator/target.svg',
|
|
'button-mapping.ui',
|
|
'wacom-stylus-3btn.svg',
|
|
'wacom-stylus-3btn-no-eraser.svg',
|
|
'wacom-stylus-airbrush.svg',
|
|
'wacom-stylus-art-pen.svg',
|
|
'wacom-stylus-classic.svg',
|
|
'wacom-stylus-inking.svg',
|
|
'wacom-stylus-no-eraser.svg',
|
|
'wacom-stylus.svg',
|
|
'wacom-tablet-cintiq.svg',
|
|
'wacom-tablet-pc.svg',
|
|
'wacom-tablet.svg'
|
|
)
|
|
|
|
common_sources += wacom_gresource
|
|
|
|
sources = common_sources + files(
|
|
'cc-' + cappletname + '-panel.c',
|
|
'cc-drawing-area.c',
|
|
'cc-wacom-ekr-page.c',
|
|
)
|
|
|
|
deps += libdevice_dep
|
|
|
|
incs = [
|
|
top_inc,
|
|
calibrator_inc
|
|
]
|
|
|
|
panels_libs += static_library(
|
|
cappletname + '-properties',
|
|
sources : sources,
|
|
include_directories : incs,
|
|
dependencies : deps,
|
|
c_args : cflags,
|
|
link_with : [ libwacom_calibrator ]
|
|
)
|
|
|
|
name = 'test-wacom'
|
|
|
|
sources = common_sources + files(name + '.c')
|
|
|
|
executable(
|
|
name,
|
|
sources,
|
|
include_directories : incs,
|
|
dependencies : deps,
|
|
c_args : test_cflags,
|
|
link_with : [ libwacom_calibrator_test ]
|
|
)
|
|
|
|
subdir('icons')
|