b0ab8136b6
* After removing the matchit.vim plugin from the vimrc.bundles file in this pull request https://github.com/thoughtbot/dotfiles/pull/379. It was brought to my attention that plugins in the macros directory are not automatically loaded due to backwards compatibility issues. * Add entry to vimrc to source the matchit.vim plugin from the macros directory, if the user does not have it installed already. This is how Tim Pope adds the matchit.vim plugin to vimrc in his vim-sensible plugin. https://github.com/tpope/vim-sensible/blob/master/plugin/sensible.vim#L88
158 lines
4.6 KiB
VimL
158 lines
4.6 KiB
VimL
" Leader
|
|
let mapleader = " "
|
|
|
|
set backspace=2 " Backspace deletes like most programs in insert mode
|
|
set nobackup
|
|
set nowritebackup
|
|
set noswapfile " http://robots.thoughtbot.com/post/18739402579/global-gitignore#comment-458413287
|
|
set history=50
|
|
set ruler " show the cursor position all the time
|
|
set showcmd " display incomplete commands
|
|
set incsearch " do incremental searching
|
|
set laststatus=2 " Always display the status line
|
|
set autowrite " Automatically :write before running commands
|
|
|
|
" Switch syntax highlighting on, when the terminal has colors
|
|
" Also switch on highlighting the last used search pattern.
|
|
if (&t_Co > 2 || has("gui_running")) && !exists("syntax_on")
|
|
syntax on
|
|
endif
|
|
|
|
if filereadable(expand("~/.vimrc.bundles"))
|
|
source ~/.vimrc.bundles
|
|
endif
|
|
|
|
" Load matchit.vim, but only if the user hasn't installed a newer version.
|
|
if !exists('g:loaded_matchit') && findfile('plugin/matchit.vim', &rtp) ==# ''
|
|
runtime! macros/matchit.vim
|
|
endif
|
|
|
|
filetype plugin indent on
|
|
|
|
augroup vimrcEx
|
|
autocmd!
|
|
|
|
" When editing a file, always jump to the last known cursor position.
|
|
" Don't do it for commit messages, when the position is invalid, or when
|
|
" inside an event handler (happens when dropping a file on gvim).
|
|
autocmd BufReadPost *
|
|
\ if &ft != 'gitcommit' && line("'\"") > 0 && line("'\"") <= line("$") |
|
|
\ exe "normal g`\"" |
|
|
\ endif
|
|
|
|
" Set syntax highlighting for specific file types
|
|
autocmd BufRead,BufNewFile Appraisals set filetype=ruby
|
|
autocmd BufRead,BufNewFile *.md set filetype=markdown
|
|
|
|
" Enable spellchecking for Markdown
|
|
autocmd FileType markdown setlocal spell
|
|
|
|
" Automatically wrap at 80 characters for Markdown
|
|
autocmd BufRead,BufNewFile *.md setlocal textwidth=80
|
|
|
|
" Automatically wrap at 72 characters and spell check git commit messages
|
|
autocmd FileType gitcommit setlocal textwidth=72
|
|
autocmd FileType gitcommit setlocal spell
|
|
|
|
" Allow stylesheets to autocomplete hyphenated words
|
|
autocmd FileType css,scss,sass setlocal iskeyword+=-
|
|
augroup END
|
|
|
|
" Softtabs, 2 spaces
|
|
set tabstop=2
|
|
set shiftwidth=2
|
|
set shiftround
|
|
set expandtab
|
|
|
|
" Display extra whitespace
|
|
set list listchars=tab:»·,trail:·,nbsp:·
|
|
|
|
" Use The Silver Searcher https://github.com/ggreer/the_silver_searcher
|
|
if executable('ag')
|
|
" Use Ag over Grep
|
|
set grepprg=ag\ --nogroup\ --nocolor
|
|
|
|
" Use ag in CtrlP for listing files. Lightning fast and respects .gitignore
|
|
let g:ctrlp_user_command = 'ag %s -l --nocolor --hidden -g ""'
|
|
|
|
" ag is fast enough that CtrlP doesn't need to cache
|
|
let g:ctrlp_use_caching = 0
|
|
endif
|
|
|
|
" Make it obvious where 80 characters is
|
|
set textwidth=80
|
|
set colorcolumn=+1
|
|
|
|
" Numbers
|
|
set number
|
|
set numberwidth=5
|
|
|
|
" Tab completion
|
|
" will insert tab at beginning of line,
|
|
" will use completion if not at beginning
|
|
set wildmode=list:longest,list:full
|
|
function! InsertTabWrapper()
|
|
let col = col('.') - 1
|
|
if !col || getline('.')[col - 1] !~ '\k'
|
|
return "\<tab>"
|
|
else
|
|
return "\<c-p>"
|
|
endif
|
|
endfunction
|
|
inoremap <Tab> <c-r>=InsertTabWrapper()<cr>
|
|
inoremap <S-Tab> <c-n>
|
|
|
|
" Exclude Javascript files in :Rtags via rails.vim due to warnings when parsing
|
|
let g:Tlist_Ctags_Cmd="ctags --exclude='*.js'"
|
|
|
|
" Index ctags from any project, including those outside Rails
|
|
map <Leader>ct :!ctags -R .<CR>
|
|
|
|
" Switch between the last two files
|
|
nnoremap <leader><leader> <c-^>
|
|
|
|
" Get off my lawn
|
|
nnoremap <Left> :echoe "Use h"<CR>
|
|
nnoremap <Right> :echoe "Use l"<CR>
|
|
nnoremap <Up> :echoe "Use k"<CR>
|
|
nnoremap <Down> :echoe "Use j"<CR>
|
|
|
|
" vim-rspec mappings
|
|
nnoremap <Leader>t :call RunCurrentSpecFile()<CR>
|
|
nnoremap <Leader>s :call RunNearestSpec()<CR>
|
|
nnoremap <Leader>l :call RunLastSpec()<CR>
|
|
|
|
" Run commands that require an interactive shell
|
|
nnoremap <Leader>r :RunInInteractiveShell<space>
|
|
|
|
" Treat <li> and <p> tags like the block tags they are
|
|
let g:html_indent_tags = 'li\|p'
|
|
|
|
" Open new split panes to right and bottom, which feels more natural
|
|
set splitbelow
|
|
set splitright
|
|
|
|
" Quicker window movement
|
|
nnoremap <C-j> <C-w>j
|
|
nnoremap <C-k> <C-w>k
|
|
nnoremap <C-h> <C-w>h
|
|
nnoremap <C-l> <C-w>l
|
|
|
|
" configure syntastic syntax checking to check on open as well as save
|
|
let g:syntastic_check_on_open=1
|
|
let g:syntastic_html_tidy_ignore_errors=[" proprietary attribute \"ng-"]
|
|
|
|
" Set spellfile to location that is guaranteed to exist, can be symlinked to
|
|
" Dropbox or kept in Git and managed outside of thoughtbot/dotfiles using rcm.
|
|
set spellfile=$HOME/.vim-spell-en.utf-8.add
|
|
|
|
" Autocomplete with dictionary words when spell check is on
|
|
set complete+=kspell
|
|
|
|
" Always use vertical diffs
|
|
set diffopt+=vertical
|
|
|
|
" Local config
|
|
if filereadable($HOME . "/.vimrc.local")
|
|
source ~/.vimrc.local
|
|
endif
|